git » sdk » main » tree

[main] / borogove / Command.hx 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
package borogove;

import thenshim.Promise;

import borogove.DataForm;
import borogove.Form;
import borogove.queries.CommandExecute;

@:expose
@:allow(borogove.CommandSession)
class Command {
	public final name: String;
	private final jid: JID;
	private final node: String;
	private final client: Client;

	@:allow(borogove)
	private function new(client: Client, params: { jid: JID, name: Null<String>, node: String }) {
		jid = params.jid;
		node = params.node;
		name = params.name ?? params.node;
		this.client = client;
	}

	/**
		Start a new session for this command. May have side effects!
	**/
	public function execute(): Promise<CommandSession> {
		return new CommandSession("executing", null, [], [], this).execute();
	}
}

@:expose
class CommandSession {
	public final name: String;
	public final status: String;
	public final actions: Array<FormOption>;
	public final forms: Array<Form>;
	private final sessionid: String;
	private final command: Command;

	@:allow(borogove)
	private function new(status: String, sessionid: String, actions: Array<FormOption>, forms: Array<Form>, command: Command) {
		this.name = forms[0]?.title() != null ? forms[0].title() : command.name;
		this.status = status;
		this.sessionid = sessionid;
		this.actions = actions;
		this.forms = forms;
		this.command = command;
	}

	#if js
	public function execute(
		action: Null<String> = null,
		data: Null<haxe.extern.EitherType<
			haxe.extern.EitherType<
				haxe.DynamicAccess<StringOrArray>,
				Map<String, StringOrArray>
			>,
			js.html.FormData
		>> = null,
		formIdx: Null<Int> = null
	)
	#else
	public function execute(
		action: Null<String> = null,
		data: Null<FormSubmitBuilder> = null,
		formIdx: Null<Int> = null
	)
	#end
	: Promise<CommandSession> {
		final extendedAction = action != null && !["prev", "next", "complete", "execute", "cancel"].contains(action);
		var toSubmit = null;
		if (data != null || extendedAction) {
			toSubmit = forms[formIdx ?? 0].submit(data);
			if (toSubmit == null && action != "cancel" && action != "prev") return Promise.reject("Invalid submission");
		}

		if (extendedAction) {
			if (toSubmit == null) toSubmit = new Stanza("x", { xmlns: "jabber:x:data", type: "submit" });
			final dataForm: DataForm = toSubmit;
			final fld = dataForm.field("http://jabber.org/protocol/commands#actions");
			if (fld == null) {
				toSubmit.tag("field", { "var": "http://jabber.org/protocol/commands#actions" }).textTag("value", action).up();
			} else {
				fld.value = [action];
			}
			action = null;
		}

		return new Promise((resolve, reject) -> {
			final exe = new CommandExecute(command.jid.asString(), command.node, action, sessionid, toSubmit);
			exe.onFinished(() -> {
				if (exe.getResult(command) == null) {
					reject(exe.responseStanza);
				} else {
					resolve(exe.getResult(command));
				}
			});
			command.client.sendQuery(exe);
		});
	}
}