git » sdk » main » tree

[main] / borogove / MucSettingsCommand.hx 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
package borogove;

import thenshim.Promise;
import borogove.Command;
import borogove.DataForm;
import borogove.Form;
import borogove.queries.MucSettingsGet;
import borogove.queries.MucSettingsSubmit;

#if cpp
import HaxeCBridge;
#end

class MucSettingsCommand extends Command {
	@:allow(borogove)
	public function new(client: Client, jid: JID) {
		super(client, { jid: jid, name: "Settings", node: "muc-settings" });
	}

	override public function execute(): Promise<CommandSession> {
		return new Promise<CommandSession>((resolve, reject) -> {
			final q = new MucSettingsGet(this.jid.asString());
			q.onFinished(() -> {
				if (q.error != null) {
					final formish = new Stanza("x", { xmlns: "jabber:x:data", type: "result" }).textTag("instructions", q.error, { type: "error" });
					resolve(new MucSettingsCommandSession("error", null, [], [new Form(formish, null)], this));
					return;
				}

				final form = q.getResult();
				if (form == null) {
					reject("Failed to get settings form");
					return;
				}

				resolve(new MucSettingsCommandSession("executing", null, [new FormOption("Submit", "execute"), new FormOption("Cancel", "cancel")], [new Form(form, null)], this));
			});
			this.client.sendQuery(q);
		});
	}
}

class MucSettingsCommandSession extends CommandSession {
	#if js
	override public function execute(
		action: Null<String> = null,
		data: Null<haxe.extern.EitherType<
			haxe.extern.EitherType<
				haxe.DynamicAccess<StringOrArray>,
				Map<String, StringOrArray>
			>,
			js.html.FormData
		>> = null,
		formIdx: Int = 0
	)
	#else
	override public function execute(
		action: Null<String> = null,
		data: Null<FormSubmitBuilder> = null,
		formIdx: Int = 0
	)
	#end
	: Promise<CommandSession> {
		if (action == "cancel" || action == "prev") {
			return Promise.resolve((new MucSettingsCommandSession("canceled", null, [], [], command) : CommandSession));
		}

		final toSubmit = forms[formIdx].submit(data);
		if (toSubmit == null) return Promise.reject("Invalid submission");

		return new Promise<CommandSession>((resolve, reject) -> {
			final q = new MucSettingsSubmit(this.command.jid.asString(), toSubmit);
			q.onFinished(() -> {
				if (q.error != null) {
					final formish = new Stanza("x", { xmlns: "jabber:x:data", type: "result" }).textTag("instructions", q.error, { type: "error" });
					resolve(new MucSettingsCommandSession("error", null, [], [new Form(formish, null)], this.command));
					return;
				}

				if (!q.getResult()) {
					reject("Failed to submit settings");
					return;
				}

				resolve(new MucSettingsCommandSession("completed", null, [], [], this.command));
			});
			this.command.client.sendQuery(q);
		});
	}
}