git » sdk » main » tree

[main] / borogove / Reaction.hx 

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
package borogove;

using StringTools;

#if cpp
import HaxeCBridge;
#end

@:nullSafety(Strict)
@:expose
#if cpp
@:build(HaxeCBridge.expose())
@:build(HaxeSwiftBridge.expose())
#end
class Reaction {
	/**
		ID of who sent this Reaction
	**/
	public final senderId: String;
	/**
		Date and time when this Reaction was sent,
		in format YYYY-MM-DDThh:mm:ss[.sss]+00:00
	**/
	public final timestamp: String;
	@:allow(borogove)
	private final text: String;
	/**
		Key for grouping reactions
	**/
	public final key: String;
	@:allow(borogove)
	private final envelopeId: Null<String>;

	@:allow(borogove)
	private function new(senderId: String, timestamp: String, text: String, envelopeId: Null<String> = null, key: Null<String> = null) {
		this.senderId = senderId;
		this.timestamp = timestamp;
		this.text = text.replace("\u{fe0f}", "");
		this.envelopeId = envelopeId;
		this.key = key ?? this.text;
	}

	/**
		Create a new Unicode reaction to send

		@param unicode emoji of the reaction
		@returns Reaction
	**/
	public static function unicode(unicode: String) {
		return new Reaction("", "", unicode);
	}

	/**
		Create a new Unicode reaction to send

		@param forText Callback called if this is a textual reaction.
		               Called with the unicode String.
		@param forImage Callback called if this is a custom/image reaction.
		               Called with the name and the URI to the image.
		@returns the return value of the callback
	**/
	#if cpp
	public function render(forText: (String) -> String, forImage: (String, String) -> String) {
	#else
	public function render<T>(forText: (String) -> T, forImage: (String, String) -> T) {
	#end
		return forText(text + "\u{fe0f}");
	}
}

@:expose
#if cpp
@:build(HaxeCBridge.expose())
@:build(HaxeSwiftBridge.expose())
#end
class CustomEmojiReaction extends Reaction {
	public final uri: String;

	@:allow(borogove)
	private function new(senderId: String, timestamp: String, text: String, uri: String, envelopeId: Null<String> = null) {
		super(senderId, timestamp, text, envelopeId, uri);
		this.uri = uri;
	}

	/**
		Create a new custom emoji reaction to send

		@param text name of custom emoji
		@param uri URI for media of custom emoji
		@returns Reaction
	**/
	public static function custom(text: String, uri: String) {
		return new CustomEmojiReaction("", "", text, uri);
	}

	#if cpp
	override public function render(forText: (String) -> String, forImage: (String, String) -> String) {
	#else
	override public function render<T>(forText: (String) -> T, forImage: (String, String) -> T) {
	#end
		final hash = Hash.fromUri(uri);
		return forImage(text, hash?.toUri() ?? uri);
	}
}