git » sdk » main » tree

[main] / borogove / Source.hx 

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
package borogove;

import haxe.io.Bytes;
import thenshim.Promise;
import tink.io.Source;

#if js
@:native("ReadableStream")
extern class ReadableStream {
	public var __source: RealSource;
	public function new(o: { pull: ({ enqueue: (js.lib.Uint8Array->Void), close: ()->Void })->Promise<Any> });
}
typedef UnderlyingSource = ReadableStream;
#else
typedef UnderlyingSource = RealSource;
#end

abstract Source(UnderlyingSource) {
	private function new(source: UnderlyingSource) {
		this = source;
	}

	@:allow(borogove)
	@:to private inline function tinkSource(): RealSource {
		#if js
		return this.__source;
		#else
		return this;
		#end
	}

	@:from public static function ofTinkSource(source: RealSource) {
		#if js
		var stream: ReadableStream = null;
		stream = new ReadableStream({
			pull: (controller) -> {
				return new Promise((resolve, reject) -> {
					stream.__source.chunked().next().handle(o -> switch o {
						case End:
							controller.close();
							resolve(null);
						case Fail(e):
							reject(e);
						case Link(chunk, next):
							stream.__source = next;
							controller.enqueue(new js.lib.Uint8Array(chunk.toBytes().getData()));
							resolve(null);
					});
				});
			}
		});
		stream.__source = source;
		return new Source(stream);
		#else
		return new Source(source);
		#end
	}

	@:from static inline function ofString(s:String) {
		return ofTinkSource((s : RealSource));
	}

	@:from static inline function ofBytes(b:Bytes) {
		return ofTinkSource((b : RealSource));
	}
}